第二部分。事件模型和交易策略原型。这部分描述一个基于集中事件处理的原始事件模型。也就是所有事件被及总在EA交易逻辑的一个地方“集中”处理。同时，事件是多货币对的。例如，一个EA运行在EURUSD图表上，也可以接收来自GBPUSD的新报价事件。这个事件处理模型在开发多货币对EA时就非常有用了。在这部分，我们还将介绍CStrategy交易引擎的基本类，以及在MetaTrader 5中表示头寸的CPositionMT5类。

第三部分。自定义策略和辅助交易类。资料涵盖了如何开发自定义EA的过程。从本文中，您将了解到如何通过一个简单的开平仓条件枚举来创建一个智能交易系统。这部分还将介绍各种辅助算法，可以大大简化访问交易信息的过程。

第四部分。用一组策略进行交易以及组构建策略组合。这部分包含将多个逻辑集成到一个单一可执行的ex5模块中的，特殊算法的介绍。还介绍了可以使用一个XML文件生成一组策略的机制。

CTradeState交易模式切换

使用交易模式开发的EA将总是能够知道某一时点执行何种交易操作。然而，每个EA应独立确定这一时点。当交易MICEX的FORTS板块，尤其需要交易模式。FORTS交易有几个特点，其中主要特点之一是每天清算两次，从14:00到14:03（中间清算）以及从18:45到19:00（主要清算）。在清算阶段建议不要允许EA进行交易操作。

当然，如果EA仅在新的报价或者新的柱形形成时执行交易，它将不会再市场关闭时运行，以为没有新的报价到来。但是很多EA在特定的时间间隔上运行（使用计时器）。对于这类EA，控制交易操作就显得十分必要。另外，有时交易可以再周末或者节假日进行，并且甚至有些外汇经纪商允许在周末进行交易。然而，由于这些日子的流动性很低，以及它们的统计意义也很弱，这些日子应该被忽略。

不管怎样，对于任何职业算法交易者而言，控制交易模式都是必要的过程。可以通过CTradeState模块来实现之。这个模块用MQL类来实现，它的任务是根据当前时段返回与之对应的交易模式。例如，如果当前时间是清算时间段，这个模块将返回TRADE_WAIT状态。如果是要平仓所有头寸的时间，那么模块返回TRADE_STOP。让我们详细描述它的操作和配置方法。下面是类的头部：

//+------------------------------------------------------------------+
//|                                                  TimeControl.mqh |
//|                                 Copyright 2015, Vasiliy Sokolov. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2015, Vasiliy Sokolov."
#property link      "https://www.mql5.com"
#include "Strategy.mqh"
#define ALL_DAYS_OF_WEEK 7
//+------------------------------------------------------------------+
//| 交易状态模块 TradeState                                            |
//+------------------------------------------------------------------+
class CTradeState
{
private:
   ENUM_TRADE_STATE  m_state[60*24*7];  // 交易状态掩码
public:
                     CTradeState(void);
                     CTradeState(ENUM_TRADE_STATE default_state);
   ENUM_TRADE_STATE  GetTradeState(void);
   ENUM_TRADE_STATE  GetTradeState(datetime time_current);
   void              SetTradeState(datetime time_begin, datetime time_end, int day_of_week, ENUM_TRADE_STATE state);
};

这个类的主要功能是返回策略的当前状态，通过调用GetTradeState方法来获得。在模块能够返回状态之前，此状态需通过SetTradeState方法进行添加。

该模块的操作算法类似于MetaTrader 5测试器中的“时间表”标签：

图 3. MetaTrader 5 测试器中的时间表标签

此窗口使你能够设置一周中哪些天可以用来执行来自MQL5云网络中的任务。CTradeState类的工作方式类似，但是允许你为每个范围设置五个ENUM_TRADE_STATE值中的一个。

为了进一步理解如何使用CTradeState，让我们配置交易状态模块。针对FORTS市场的日常操作，本文的笔者使用下面的配置表：

表 3. 基于时间的交易模式

从表中可见，进行必要的配置并不是一件困难的事情，相反CTradeState类使你能够创建此类的模式组合。下面是一个简单的监本，设置表格中的模式，然后请求符合特定时间的模式：

//+------------------------------------------------------------------+
//|                                               TestTradeState.mq5 |
//|                                 Copyright 2015, Vasiliy Sokolov. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2015, Vasiliy Sokolov."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Strategy/TradeState.mqh>

CTradeState TradeState(TRADE_BUY_AND_SELL);  // 设置默认模式为Buy和Sell 
//+------------------------------------------------------------------+
//| 脚本程序start函数                                                  |
//+------------------------------------------------------------------+
void OnStart()
{
   TradeState.SetTradeState(D'15:00', D'23:39', FRIDAY, TRADE_NO_NEW_ENTRY);
   TradeState.SetTradeState(D'10:00', D'10:01', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'14:00', D'14:03', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'18:45', D'18:59', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'23:50', D'23:59', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'0:00',  D'9:59',  ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'23:40', D'23:49', FRIDAY, TRADE_STOP);
   TradeState.SetTradeState(D'00:00', D'23:59', SATURDAY, TRADE_WAIT);
   TradeState.SetTradeState(D'00:00', D'23:59', SUNDAY, TRADE_WAIT);
   
   printf("10:00 - " + EnumToString(TradeState.GetTradeState(D'10:00')));
   printf("14:01 - " + EnumToString(TradeState.GetTradeState(D'14:01')));
   printf("18:50 - " + EnumToString(TradeState.GetTradeState(D'18:50')));
   printf("23:50 - " + EnumToString(TradeState.GetTradeState(D'23:51')));
   printf("Friday, > 15:00 - " + EnumToString(TradeState.GetTradeState(D'2015.11.27 15:00')));
   printf("Saturday - " + EnumToString(TradeState.GetTradeState(D'2015.11.28')));
   printf("Sunday - " + EnumToString(TradeState.GetTradeState(D'2015.11.29')));
   printf("Default State - " + EnumToString(TradeState.GetTradeState(D'11:40')));
}
//+------------------------------------------------------------------+

脚本的输出将是这样的：

默认状态- TRADE_BUY_AND_SELL
周日 - TRADE_WAIT
周六 - TRADE_WAIT
周五， > 15:00 - TRADE_NO_NEW_ENTRY
23:50 - TRADE_STOP
18:50 - TRADE_WAIT
14:01 - TRADE_WAIT
10:00 - TRADE_WAIT

请注意交易模式设置的格式。它们不使用日期，仅使用小时和分钟（D’15:00′ or D’18:40’）。它将完整的日期传入方法中，例如：

TradeState.SetTradeState(D'2015.11.27 15:00', D'2015.11.27 23:39', FRIDAY, TRADE_NO_NEW_ENTRY);

但日期部分仍将被忽略。

其次要注意的是SetTradeState的调用顺序。顺序很重要！CTradeState 模块把交易状态的掩码作为 ENUM_TRADE_STATE 数组存储，其中元素的编号等于一周中的分钟数（10080个元素）。使用传入的日期，SetTradeState方法计算此数组元素的范围并用合适的状态进行填充。这意味着先前的状态被新的状态替代。因此，最近更新的是最后的状态。这个函数的代码如下：

//+------------------------------------------------------------------+
//| 设置交易状态 TradeState                                            |
//| 输入：                                                            |
//| time_begin  - 时间，从此时开始交易状态有效                           |
//|                                                                  |
//| time_end    - 时间，交易状态失效时间                                |
//| day_of_week - 星期几，交易状态的设置应用于哪一天                      |
//|               根据修饰符确定                                       |
//|               ENUM_DAY_OF_WEEK 或者 ALL_DAYS_OF_WEEK              |
//| state       - 交易状态。                                           |
//| 注意：time_begin 和 time_end 对应的日期被忽略。                      |
//+------------------------------------------------------------------+
void CTradeState::SetTradeState(datetime time_begin,datetime time_end, int day_of_week, ENUM_TRADE_STATE state)
{
   if(time_begin > time_end)
   {
      string sb = TimeToString(time_begin, TIME_MINUTES);
      string se = TimeToString(time_end, TIME_MINUTES);
      printf("Time " + sb + " must be more time " + se);
      return;
   }
   MqlDateTime btime, etime;
   TimeToStruct(time_begin, btime);
   TimeToStruct(time_end,  etime);
   for(int day = 0; day < ALL_DAYS_OF_WEEK; day++)
   {
      if(day != day_of_week && day_of_week != ALL_DAYS_OF_WEEK)
         continue;
      int i_day = day*60*24;
      int i_begin = i_day + (btime.hour*60) + btime.min;
      int i_end = i_day + (etime.hour*60) + etime.min;
      for(int i = i_begin; i <= i_end; i++)
         m_state[i] = state;
   }
}

GetTradeState 简单些。它根据请求时间计算数组元素的索引，然后返回元素的值。

//+------------------------------------------------------------------+
//| 根据传入的时间，返回先前设置的交易状态                                |
//|                                                                  |
//+------------------------------------------------------------------+
ENUM_TRADE_STATE CTradeState::GetTradeState(datetime time_current)
{
   MqlDateTime dt;
   TimeToStruct(time_current, dt);
   int i_day = dt.day_of_week*60*24;
   int index = i_day + (dt.hour*60) + dt.min;
   return m_state[index];
}

CTradeState 类的完整代码在 TradeState.mqh 文件中，并且被包含在所述交易引擎的源代码里面。下一篇文章将介绍这个类是如何在交易引擎中运作的。